tool to monitor when internet drops

[Rafa]

Is there a free tool or any that Win10 can do to monitor when internet drops with a timestamp that you guys can recommend.

Bonus: if it can tell you how long it stays down too.


Been having major issues with my internet and had complete new drops done, new equipment at home,etc, etc.

Like to be able to monitor that and check here and there. Want to make sure when it does the ping, it does not bottleneck any bandwidth with those pings.


Thanks

[Tx Redneck]

I use a desktop gadget to monitor my connection, it logs total xfer by the day, but I don't think it logs if/when it drops. This will regularly check you speeds and log it, but I don't think it's intended to say we can reach x site at this moment.

Edit: A quick google turn up w/this. https://www.groovypost.com/howto/aut...nnection-drop/

[Nash B.]

I can write a little app if you can't find anything that works the way you want

[Rafa]

Thanks ...looked pretty simple, just doesn't say how to put that in a log.txt I can view.



Nash, I found this. Not sure if this is something you would recommend, but seems it would do what I want. Just not up to par on the script/code to make sure it's legit for me. Don't want to do this and it does something else I don't know about.




I did find this:

http://testmy.net/ipb/topic/32879-internet-uptime-monitor/

Thanks

[Rafa]

I went ahead and tried the above batch and it does work. Also saves to log each time it connects/disconnects. Doesn't over write, just adds new lines.


I was searching and couldn't come up with anything I could use. The link Brian posted would of worked, but windows 10 got rid of the "display message" after reading more of it. When Nash mentioned writing up a app, I searched for scripts instead and found above link.

I'm good now. Thanks ya'll

[Nash B.]

Looks like it does everything it says it does.

@echo off
set Delay=30

echo Connection log script started: %date% %time:~0,5%
echo Connection log script started: %date% %time:~0,5% >>"Outage log.txt"

Setting the delay counter to 30 (it's the number of times to ping localhost, not actually 30 seconds), writing start date and time to the console and to Outage Log.txt

:repeat
ping -n %Delay% localhost >nul
ping -n 1 www.google.ie >nul &&goto repeat

Setting up the main loop, pinging localhost Delay number of times (30). After it's finished, ping google.ie (Google Ireland) 1 time. Maybe change it to google.com. If the ping was successful, repeat. If not, continue below:

set OutageTime=%time:~0,5%
set OutageDate=%date%
ping -n 1 www.google.com >nul &&goto repeat
ping -n 1 www.google.com >nul &&goto repeat
echo %date% %time:~0,5% - Internet or DNS connection is down

Collect outage date and time and try pinging google.com twice. If either of those succeeds, go back to the beginning of the main loop. I'd move the outage date and time to after pinging google.com because it'll get ignored if either ping is successful. If both google.com pings fail, write to console that connection is down and continue below:

:outagerep
ping -n 1 www.google.ie >nul &&goto backonline
goto outagerep

Keep pinging google.ie until it succeeds; when it finally succeeds, go to the backonline label below:

:backonline
set UpDate=
if not "%date%"=="%OutageDate%" set UpDate= %date%
echo Link/DNS outage: %OutageDate% %OutageTime% to%UpDate% %time:~0,5% >>"Outage log.txt"
echo %date% %time:~0,5% - Internet or DNS connection is up

When it's back online, record the reconnection date and log the outage details to Outage Log.txt and write connection is back up to console. Then go back to the very beginning and start all over.

goto repeat

[Rafa]

Looks like it does everything it says it does.

..........

1. Do you think the 30 pings is too much? Want to make sure that this doesn't cause any issue with flooding network with too many pings that could cause it do lose signal/drop packets?

@echo off
set Delay=30

echo Connection log script started: %date% %time:~0,5%
echo Connection log script started: %date% %time:~0,5% >>"Outage log.txt"

2. Is this the right spot move the date/time?

ping -n 1 www.google.com >nul &&goto repeat
ping -n 1 www.google.com >nul &&goto repeat
set OutageTime=%time:~0,5%
set OutageDate=%date%

echo %date% %time:~0,5% - Internet or DNS connection is down

Thanks

[John -- '02 HAWK]

is there a way do an effective speed test using this method?

[Nash B.]

1. Do you think the 30 pings is too much? Want to make sure that this doesn't cause any issue with flooding network with too many pings that could cause it do lose signal/drop packets?

@echo off
set Delay=30

echo Connection log script started: %date% %time:~0,5%
echo Connection log script started: %date% %time:~0,5% >>"Outage log.txt"

I don't think it would add any additional load to the network. Alternatively, you could replace it with "SLEEP %Delay%" and it would pause for %Delay% seconds.

http://www.robvanderwoude.com/wait.php#PAUSE

2. Is this the right spot move the date/time?

ping -n 1 www.google.com >nul &&goto repeat
ping -n 1 www.google.com >nul &&goto repeat
set OutageTime=%time:~0,5%
set OutageDate=%date%

echo %date% %time:~0,5% - Internet or DNS connection is down

Thanks

Yeah, that's where I'd put it. It won't assign OutageTime and OutageDate until the pings fails; if they succeed, it'll go back to the start of the loop.

[ceyko]

You'd be hard pressed for a single host to do any noticeable load on a modern network via ICMP.

When I am doing this sort of thing, I leverage ping plotter.